************************************************************************
* Program ID   : ALTER
* Description  : Call SYSEXT/SYSTEM.USR0080N: Alter Editor Status Values
* Date Written : 2006-04-17
* Date Updated : 2006-04-18
* Author       : Richard J. Mills               (eMail: R3M2000@cs.com)
************************************************************************
DEFINE DATA LOCAL
01 #USR0080N-PARAMS                         /* Parameters for CALLNAT
  02 ACTION        (A08)    INIT <'GET'>    /* "GET" or "SET"
  02 TYPE          (A01)                    /* Type of Source
  02 NAME          (A08)                    /* Name of source
  02 EMPTY         ( L )                    /* TRUE if editor is empty
  02 RESPONSE      (N04)                    /* Error during execution
  02 ERROR-TEXT    (A65)                    /* Short text
*
01 TYPE-TEXT       (A13)                    /* Expantion of TYPE
END-DEFINE
* ======================================================================
CALLNAT 'USR0080N' #USR0080N-PARAMS
* ======================================================================
DECIDE ON FIRST TYPE
  VALUE 'P' MOVE '(Program)'     TO TYPE-TEXT
  VALUE 'S' MOVE '(Subroutine)'  TO TYPE-TEXT
  VALUE 'H' MOVE '(Helproutine)' TO TYPE-TEXT
  VALUE 'N' MOVE '(Subprogram)'  TO TYPE-TEXT
  VALUE 'C' MOVE '(Copycode)'    TO TYPE-TEXT
  VALUE 'T' MOVE '(Text)'        TO TYPE-TEXT
  VALUE 'G' MOVE '(GDA)'         TO TYPE-TEXT
  VALUE 'L' MOVE '(LDA)'         TO TYPE-TEXT
  VALUE 'A' MOVE '(PDA)'         TO TYPE-TEXT
  VALUE 'M' MOVE '(Map)'         TO TYPE-TEXT
  VALUE '3' MOVE '(Dialog)'      TO TYPE-TEXT      /* not on Mainframe |
  VALUE '4' MOVE '(Class)'       TO TYPE-TEXT
  VALUE 'O' MOVE '(Macro)'       TO TYPE-TEXT      /* only for ISPF/MF |
  NONE      MOVE '(?)'           TO TYPE-TEXT
END-DECIDE
* ----------------------------------------------------------------------
ACTION := 'SET'
INPUT (AD=MITL IP=OFF ZP=ON SG=OFF)
    1/1   'Prog:' *PROGRAM            72T *DATE
    2/1   'Lib :' *LIBRARY-ID         72T *TIMX (EM=HH:II:SS)
    4/20  'ALTER/SET Natural Editor Details'
     /20T '================================'
    //18T 'Editor empty ...............' EMPTY (AD=OI EM=NO/YES)
    //18T 'Name of source in editor ...' NAME  (AD='_')
     /18T 'Type of source in editor ...' TYPE 5X TYPE-TEXT (AD=R CD=NE)
    //18T '-'(19)                     47T  '-'(19)
     /18T 'P - Program'    (CD=GR)    47T  'G - GDA'   (CD=YE)
     /18T 'S - Subroutine' (CD=GR)    47T  'L - LDA'   (CD=YE)
     /18T 'N - Subprogram' (CD=GR)    47T  'A - PDA'   (CD=YE)
     /18T 'H - Helproutine'(CD=RE)    47T  'M - Map'   (CD=RE)
     /18T 'C - Copycode'   (CD=TU)    47T  '4 - Class' (CD=BL)
     /18T 'T - Text'       (CD=TU)    47T  'O - Macro' (CD=NE)
**** /18T '3 - Dialog (PC Only)'
     /18T '-'(19)                     47T  '-'(19)
   22/32   ' <PF3>:Exit ' (CD=RE AD=V)
* ----------------------------------------------------------------------
IF *PF-KEY NE 'PF3'
  CALLNAT 'USR0080N' #USR0080N-PARAMS
END-IF
* ======================================================================
END